#!load ntime.hsm

#sadrzaj:
#
#NickGroupOpen
#NickHeaderGet($text, $header)
#NickHeaderClean($text)
#NickCleanQuote($text)
#findbinary($handle, $min, $max, $date)
#TextClean($text)


####pita ime grupe, provjerava pravilnost i vraca ime grupe####
sub NickGroupOpen
var($grupa, $ok, $index)

  repeat
    $grupa = InputBox( "Upisite ime grupe", "Ime grupe", "", $ok )
    if ($ok == 0)
      quit
    endif
    $index = HamGroupIndex($grupa)
  until ($index != -1)

  return($grupa)
endsub

####iz teksta clanka vraca ulazni header####
sub NickHeaderGet($text, $header)
var($result)

  if (pos($header, $text))
    $result = $text
    $result = delete($result, 1, pos($header, $result) + len($header) + 1)
    $result = delete($result, pos(chr(13), $result), len($result) - pos(chr(13), $result) + 1)
    return($result)
  else
    return("")
  endif

endsub

####iz primljenog clanka brise headere####
sub NickHeaderClean($text)
var($prazline)

$prazline = chr(13) + chr(10) + chr(13) + chr(10)

$text = delete($text, 1, pos($prazline, $text) + 3)

return($text)

endsub

####iz primljenog clanka brise quotani text####
sub NickCleanQuote($text)
var($i, $quot1, $quot2, $quot3, $newline, $text2)

$quot1= chr(13) + chr(10) + ">"
$quot2= chr(13) + chr(10) + ":"
$quot3= chr(13) + chr(10) + "|"
$newline = chr(13) + chr(10)

$i = 1
while ($i <= len($text))
  if ((copy($text, $i, 3) = $quot1) | (copy($text, $i, 3) = $quot2) | (copy($text, $i, 3) = $quot3))
    $text = delete($text, $i, pos($newline, $text, $i + 1) - $i)
  else
    $i = $i + 1
  endif
endwhile

return($text)

endsub

sub findbinary($handle, $min, $max, $date)
var($id)

$id = ($max + $min) / 2
if (($max != $id) && ($min != $id))
  if (NickOlderDate(NickHeaderToDate(NickHeaderGet(HamArtText($handle, $id), "Date")), $date) != 0)
    if (NickOlderDate(NickHeaderToDate(NickHeaderGet(HamArtText($handle, $id), "Date")), $date) == 1)
      $id=findbinary($handle, $id, $max, $date)
    else
      $id=findbinary($handle, $min, $id, $date)
    endif
  endif
else
  $id = $min
endif

return($id)
endsub

sub TextClean($text)

  $text = NickHeaderClean($text)
  $text = NickCleanQuote($text)
  
  return($text)

endsub